Your function takes arguments to calculate the arithmetic mean, but then within the function it attempts to calculate the arithmetic mean for all channels within a channel group. I suggest you study my Data Portal script example at: http://www.savvydiademsolutions.com/dataportal.php?topic=data-portal-basics
Meanwhile, I have provided you two functions. One that calculates the for one channel by the specified row range, and another for all channels within a specified channel group. I also present a more direct way to calculate the arithmetic mean for one or more channels. Note my first example where I define "Dim oElementList: Set oElementList = Data.CreateElementList" and then pass oElementList to ChnStatisticsChannelCalc(). For most DIAdem functions & commands, you may pass either a channel list variable (oElementList), or a channel object variable (oChn). These examples should clarify several issues.
Option Explicit
Call LogFileDel
'Load a DIAdem example data file
Call Data.Root.Clear
Call DataFileLoadSel(sFilePathDIAdemExample("Example.tdm"),,"[1]/*")
'Highlight the commented rows below and use 'Shift-Ctrl-D' to uncomment the lines.
'Then run the script to observe the function running.
'Highlight the rows below again and use 'Ctrl-D' to re-comment the lines.
''Calculate the arithmetic mean for all channels in the last channel group (excluding the first channe "Time")
'Dim oElementList: Set oElementList = Data.CreateElementList
'Dim i
'For i = 2 To Data.Root.ChannelGroups(1).Channels.Count
' Call oElementList.Add(Data.Root.ChannelGroups(1).Channels(i))
'Next
'Call ChnStatisticsChannelCalc(oElementList,eStatsArithmeticMean,1,Data.Root.ChannelGroups(1).Channels(1).Size,False,False)
''Calculate the arithmetic mean for the the 2nd channel in the first channel group
'Call LogFileWrite("dChnMeanByRows() = " & dChnMeanByRows(1, 2, 1, Data.Root.ChannelGroups(1).Channels(2).Size))
'Calculate the arithmetric mean for all of the channels in the first channel group
If Not bGrpChnMeanByRows(1, 1, Data.Root.ChannelGroups(1).Channels(2).Size) Then Call Err.Raise(65535,,"ERROR - invalid parameters or channels passed to bGrpChnMeanByRows()")
Function dChnMeanByRows(iGrpNum, iChnNum, iRowStart, iRowEnd)
dChnMeanByRows = NoValue
If Data.Root.ChannelGroups.Count = 0 Then Exit Function
'Validate the function arguments iGrpNum, iChnNum, iRowStart, iRowEnd
If IsEmpty(iGrpNum) OR iGrpNum < 1 Then Call Err.Raise(65535,,"ERROR - invalid function argument iGrpNum = '" & iGrpNum & "'")
If IsEmpty(iChnNum) OR iChnNum < 1 Then Call Err.Raise(65535,,"ERROR - invalid function argument iChnNum = '" & iChnNum & "'")
If IsEmpty(iRowStart) OR iRowStart < 1 Then iRowStart = 1
If IsEmpty(iRowEnd) OR iRowEnd < 1 Then iRowEnd = Data.Root.ChannelGroups(iGrpNum).Channels(iChnNum).Size
Dim oGrp, oChn
Set oGrp = Data.Root.ChannelGroups(iGrpNum)
Set oChn = oGrp.Channels(iChnNum)
If oChn.DataType = DataTypeChnFloat64 AND oChn.IsKindOf(eDataChannel) Then
Call ChnStatisticsChannelCalc(oChn, eStatsArithmeticMean, iRowStart, iRowEnd, False, False)
'The arithmetic mean has been added to oChn as a property named: "Result~Statistics~MeanValues~ArithmeticMean"
dChnMeanByRows = oChn.Properties("Result~Statistics~MeanValues~ArithmeticMean").Value
End If
Set oChn = Nothing: Set oGrp = Nothing
End Function 'dChnMeanByRows()
Function bGrpChnMeanByRows(iGrpNum, iRowStart, iRowEnd)
bGrpChnMeanByRows = False
If Data.Root.ChannelGroups.Count = 0 Then Exit Function
'Validate the function arguments iGrpNum, iChnNum, iRowStart, iRowEnd
If IsEmpty(iGrpNum) OR iGrpNum < 1 Then Call Err.Raise(65535,,"ERROR - invalid function argument iGrpNum = '" & iGrpNum & "'")
If IsEmpty(iRowStart) OR iRowStart < 1 Then iRowStart = 1
If IsEmpty(iRowEnd) OR iRowEnd < 1 Then iRowEnd = Data.Root.ChannelGroups(iGrpNum).Channels(iChnNum).Size
Dim oGrp, oChn, iChn
Set oGrp = Data.Root.ChannelGroups(iGrpNum)
For iChn = 1 To oGrp.Channels.Count
Set oChn = oGrp.Channels(iChn)
If oChn.DataType = DataTypeChnFloat64 AND oChn.IsKindOf(eDataChannel) Then
Call ChnStatisticsChannelCalc(oChn, eStatsArithmeticMean, iRowStart, iRowEnd, False, False)
'The arithmetic mean has been added to oChn as a property named: "Result~Statistics~MeanValues~ArithmeticMean"
End If
Next
Set oChn = Nothing: Set oGrp = Nothing
bGrpChnMeanByRows = True
End Function 'bGrpChnMeanByRows()
Function sFilePathDIAdemExample(ByVal sFilename)
'Returns the full absolute file/path for the location of the DIAdem
'example (TDM/TDMS) file sFilename. Looks in the usual places.
'Returns "" if the file cannot be found.
'v20191119
sFilePathDIAdemExample = ""
Dim arrFilePaths, sFilePath, sFolder: ReDim arrFolders(2): arrFolders(0) = ProgramDrv: arrFolders(1) = CommonDocumentsPath: arrFolders(2) = GetEnv("PUBLIC")
For Each sFolder In arrFolders
arrFilePaths = DirListGet(sFolder,sFilename,"Date/Time","FullFilenamesRecursive")
If IsArray(arrFilePaths) Then
For Each sFilePath In arrFilePaths
If InStr(1,sFilePath,"Libr",vbTextCompare) = 0 Then sFilePathDIAdemExample = sFilePath: Exit For
Next
End If
If Len(sFilePathDIAdemExample) > 0 Then Exit For
Next
If IsArray(arrFilePaths) Then Call Erase(arrFilePaths)
If IsArray(arrFolders) Then Call Erase(arrFolders)
End Function 'sFilePathDIAdemExample()
