Dear Mr. Groß-Venhouse,
in following link explained how to import new model in multisim:
http://zone.ni.com/devzone/cda/tut/p/id/3173
In Step 6 you the the spice model by loading from file button you select there your *.lib
Then you remove the other models you don´t need because you can only import one model and there are more models.
The Component Wizard (Bauteileditor, Bauteil erzeugen, neues Bauteil unter Werkzeuge/Tools) combine the footprint with pins and model - so you can work with it. The link is for Multisim 9 but identical for former multisim versions.
I don´t have EWB 5 but it must work by a similar way...
Here´s an example of one model of the *.lib from your link
.SUBCKT MC33363/ON 1 3 4 6 7 8 9 10 11 16
+ PARAMS: RDSON=14
* STR VCC GND RT CT REG COMP VF OVL DRAIN
**** ISUPPLY ****
GSUPP 3 4 VALUE = { IF( V(33)<3.5, 250U, 3.5M ) }
**** REFERENCE VOLTAGE ****
EREF 80 4 VALUE = { IF( V(3)<7.7, V(3)-1.2, 6.5 ) }
ROUT 80 8 10
**** STARTUP AND UVLO ****
XUVLO 3 81 UVLO_33363
XOVL 60 11 82 COMP2_33363
GSTRT 1 3 VALUE = { IF( V(81)<3.5, (14M*((14-V(3))/14)+6M), 40U ) }
XAND 81 82 33 AND2_33363
**** OSCILLATOR SECTION ****
GCHG 4 7 VALUE = { IF( ((V(INV1)>500M) & (V(33)>3.5)), I(VIRT)*4, 0 ) }
GDIS 7 4 VALUE = { IF( V(INV1)<500M, I(VIRT)*4, 0 ) }
DUV 7 33 DUV
VSET 21 4 1.25V
VIRT 21 6
VREF1 22 4 2.5V
RI 22 23 40K
RF 23 INV1 10K
ECMP CLK 4 VALUE = { IF( (V(7)-V(23)>0), 5, 0 ) }
EINV 25 4 VALUE = { IF( V(CLK)<500M, 2.5, 0 ) }
RDEL1 25 INV1 100
CEL2 INV1 4 100P
**** PWM AND LATCH ****
XPWM 7 9 31 COMP2_33363
XOR1 33 31 32 34 OR3_IN_INV_33363
XNAND1 34 CLK 35 AND_IN_INV_33363
XFFLOP 35 34 36 37 FFLOP_33363
XNAND2 CLK 36 33 450 3 AND3_IN_INV_33363
RDRV 450 DRV 100
**** ERROR AMPLIFIER ****
VREF2 60 4 2.6V
XERR 60 10 9 4 ERRAMP_33363 ; + - OUT GND
**** CURRENT LIMIT COMPARATOR ****
RLIMIT 40 4 450
G225 4 40 VALUE = { I(VIRT)*2.25 }
XCOMP 50 40 32 COMPDEL_33363
**** MOSFET MODEL ****
CIN DRV 4 200pF
SMOS 16 71 DRV 4 MOS
VISRC 71 4
**** KELVIN AND L.E.B. ****
GIKEL 4 50 VALUE = { IF( V(DRV)>V(3)-0.7, I(VISRC)/51.2, 0 ) }
RKEL 50 4 9
.MODEL MOS VSWITCH (RON={RDSON} ROFF=1MEG VON=3 VOFF=1)
.MODEL DUV D RS=100M TT=50N CJO=10P N=0.1
.ENDS
**** DELAYED COMPARATOR ****
.SUBCKT COMPDEL_33363 1 2 3
* + - Out
E1 4 0 VALUE = { IF( V(1) > V(2), 1V, 0 ) }
RT 4 5 100
CT 5 0 3.36NF
E2 10 0 VALUE = { IF( V(5) > 500M, 5V, 0 ) }
RD 10 3 100
CD 3 0 100P
.ENDS
**** UVLO CIRCUIT ****
.SUBCKT UVLO_33363 1 3
* VIN OUT
Vref 10 0 5V
X1 10 3 1 0 SWhyste_33363 params: RON=1 ROFF=1MEG VT=12 VH=2.5
RUV 3 0 1k
.ENDS
**** T FFLOP Circuit ****
.SUBCKT FFLOP_33363 6 8 2 1
* S R Q Q\
EQB 10 0 VALUE = { IF ( (V(8)<800M) & (V(2)>800M), 0, 5V ) }
EQ 20 0 VALUE = { IF ( (V(6)<800M) & (V(1)>800M), 0, 5V ) }
RD1 10 1 100
CD1 1 0 10P IC=5
RD2 20 2 100
CD2 2 0 10P IC=0
.ENDS
**** 2 INPUT, ONE INPUT IS INV, AND CIRCUIT ****
.SUBCKT AND_IN_INV_33363 1 2 3
* INV NINV OUT
E1 4 0 VALUE = { IF( ((V(1)<3.5V) & (V(2)>800M)), 5V, 0 ) }
RD 4 3 100
CD 3 0 10P
.ENDS
**** 3 INPUT, ONE INPUT IS INV. AND CIRCUIT ****
.SUBCKT AND3_IN_INV_33363 1 2 3 4 6
* INV NINV NINV OUT VCC
E1 5 0 VALUE = { IF( ((V(1)<3.5V) & (V(2)>800M) & (V(3)>800M)), V(6), 0 ) }
RD 5 4 10
CD 4 0 100P
.ENDS
**** 3 INPUT, ONE INPUT IS INV. OR CIRCUIT ****
.SUBCKT OR3_IN_INV_33363 1 2 3 4
* INV NINV NINV OUT
E1 5 0 VALUE = { IF( ((V(1)<3.5V) | (V(2)>800M) | (V(3)>800M)), 5V, 0 ) }
RD 5 4 100
CD 4 0 10P
.ENDS
**** 2 INPUT AND CIRCUIT ****
.SUBCKT AND2_33363 1 2 3
E1 4 0 VALUE = { IF( ((V(1)>800M) & (V(2)>800M)), 5V, 0 ) }
RD 4 3 100
CD 3 0 10P
.ENDS
**** 2 INPUT NOR CIRCUIT ****
.SUBCKT NOR2_33363 1 2 3
E1 4 0 VALUE = { IF( ((V(1)>800M) | (V(2)>800M)), 0V, 5 ) }
RD 4 3 100
CD 3 0 10P
.ENDS
**** 2 INPUT COMPARATOR ****
.SUBCKT COMP2_33363 1 2 3
* + - S
E1 4 0 VALUE = { IF( (V(1) > V(2)), 5V, 0 ) }
RD 4 3 100
CD 3 0 10P
.ENDS
**** ERROR AMPLIFIER MODEL ****
.SUBCKT ERRAMP_33363 20 8 3 21
* + - OUT GND
RIN 20 8 8MEG
CP1 11 21 11.5P ; {1/(6.28*(GAIN/100U)*POLE)}
E1 5 21 11 21 1
R9 5 2 5
D14 2 13 DMOD
ISINK 13 21 2.7U ; {ISINK/100} in mA
Q1 21 13 16 QPMOD
ISOURCE 7 3 100u ; {ISOURCE} in uA
D12 3 7 DMOD
D15 21 11 DCLAMP
G1 21 11 20 8 100U
V1 7 21 5.8 ; Vhigh - 0.6V
V4 3 16 250M ; Vlow - 38mV
RP1 11 21 125.9MEG ; {GAIN/100U}
.MODEL QPMOD PNP
.MODEL DCLAMP D (RS=10 BV=5 IBV=0.01)
.MODEL DMOD D TT=1N CJO=10P
.ENDS
****
.subckt SWhyste_33363 NodeMinus NodePlus Plus Minus PARAMS: RON=1 ROFF=1MEG
+ VT=5 VH=2
S5 NodePlus NodeMinus 8 0 smoothSW
EBcrtl 8 0 Value = { IF ( V(plus)-V(minus) > V(ref), 1, 0 ) }
EBref ref1 0 Value = { IF ( V(8) > 0.5, {VT-VH}, {VT+VH} ) }
Rdel1 ref1 ref 100
Cdel1 ref 0 100p IC={VT+VH}
Rconv1 8 0 10Meg
Rconv2 plus 0 10Meg
Rconv3 minus 0 10Meg
.model smoothSW VSWITCH (RON={RON} ROFF={ROFF} VON=1 VOFF=0)
.ends
***** END OF MC33363 INTERNAL MODELS *****
Hope i can help you
Best Regards
ApplicationsEngineer from NI Munich
