About LM386 again

[tipa]

Привет форумчане! Нашёл две съедобные для Мультисим модели. Обе страдают одним недостатком,- потребляют ток только в одном полупериоде. Незначительно отличается выходная мощность. Кто исправит  недостатки?

original*.subckt LM386 inn inp byp g1 g8 out vs gnd

* input emitter-follower buffers:

q1 gnd inn 10011 ddpnp
r1 inn gnd 50k
q2 gnd inp 10012 ddpnp
r2 inp gnd 50k

* differential input stage, gain-setting
* resistors, and internal feedback resistor:

q3 10013 10011 10008 ddpnp
q4 10014 10012 g1 ddpnp
r3 vs byp 15k
r4 byp 10008 15k
r5 10008 g8 150
r6 g8 g1 1.35k
r7 g1 out 15k

* input stage current mirror:

q5 10013 10013 gnd ddnpn
q6 10014 10013 gnd ddnpn

* voltage gain stage & rolloff cap:

q7 10017 10014 gnd ddnpn
c1 10014 10017 15pf

* current mirror source for gain stage:

i1 10002 vs dc 5m
q8 10004 10002 vs ddpnp
q9 10002 10002 vs ddpnp

* Sziklai-connected push-pull output stage:

q10 10018 10017 out ddpnp
q11 10004 10004 10009 ddnpn 100
q12 10009 10009 10017 ddnpn 100
q13 vs 10004 out ddnpn 100
q14 out 10018 gnd ddnpn 100

* generic transistor models generated
* with MicroSim's PARTs utility, using
* default parameters except Bf:

.model ddnpn NPN(Is=10f Xti=3 Eg=1.11 Vaf=100
+ Bf=400 Ise=0 Ne=1.5 Ikf=0 Nk=.5 Xtb=1.5 Var=100
+ Br=1 Isc=0 Nc=2 Ikr=0 Rc=0 Cjc=2p Mjc=.3333
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n
+ Tf=1n Itf=1 Xtf=0 Vtf=10)

.model ddpnp PNP(Is=10f Xti=3 Eg=1.11 Vaf=100
+ Bf=200 Ise=0 Ne=1.5 Ikf=0 Nk=.5 Xtb=1.5 Var=100
+ Br=1 Isc=0 Nc=2 Ikr=0 Rc=0 Cjc=2p Mjc=.3333
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n
+ Tf=1n Itf=1 Xtf=0 Vtf=10)

.ends
*----------end of subcircuit model-----------

 Иследующая модель
.subckt LM386EE inn inp byp g1 g8 out vs gnd
*
.param
+ Rbval = 28.25k
+ Re1val = 100
+ Re2val = 1k
+ Re3val = 4
+ Rcval = 10
**
* Input stage
Q1 0 INN q1e 0 PNP1
R1 INN 0 50k
Q2 0 INP q2e 0 PNP1
R2 INP 0 50k
Q3 0 q1e q4e 0 PNP1
Q4 q4c q1e q4e 0 PNP1
Q5 0 q2e q6e 0 PNP1
Q6 q15b q2e q6e 0 PNP1
**
* Input stage current mirror
Q7 q4c q4c 0 0 NPN
Q8 q15b q4c 0 0 NPN
**
* Input bias curent and gain setting resistors
R3 q4e q1e {Rbval}
R4 g0 q4e {Re1val}
R5 q2e q6e {Rbval}
R6 G1 q6e {Re1val}
R7 G8 g0 150
R8 G1 G8 1.35k
R9 OUT G1 15k
R10 BYP g0 15k
R11 q10c BYP 15k
**
* Tail and PNP emitter follower current mirror
Q9 0 q10c q10b 0 PNP1
Q10 q10c q10b VS 0 PNP1
Q11 q11c q10b VS 0 PNP1
Q12 q12c q10b VS 0 PNP1
**
* Emitter follower buffers and
* quiescent current control
Q13 0 q4c q11c 0 PNP2
Q14 q18b q11c q14e 0 NPN
R12 q14e 0 {Re2val}
Q15 0 q15b q12c 0 PNP2
Q16 q18b q12c q17b 0 NPN
**
* Voltage gain stage
Q17 q23b q17b 0 0 NPN
C2 q23b 0 1p
**
* Crossover distortion/quiescent current mirror.
Q18 q18b q18b VS 0 PNP2
Q19 comp q18b VS 0 PNP2
Q20 q25b q18b VS 0 PNP2
**
* Crossover drop diodes and compensation cap.
Q21 comp comp q22b 0 NPN 5
C1 comp q15b 15p
R13 q25b comp {Rcval}
Q22 q25b q22b q23b 0 NPN 5
**
* Push-pull output stage with Sziklai pair.
Q23 q24b q23b q23e 0 PNP2
Q24 q23e q24b 0 0 NPN 100
R14 OUT q23e {Re3val}
Q25 VS q25b q25e 0 NPN 100
R15 q25e OUT {Re3val}
**
* Models
.model NPN NPN(IS=1E-14 VAF=100 BF=400 IKF=0.4
+ XTB=1.5 BR=4 CJC=1E-12 ITF=1 VTF=2 XTF=3)
.model PNP1 PNP(IS=1E-14 VAF=100 BF=100 IKF=0.4
+ XTB=1.5 BR=4 CJC=1E-12 ITF=1 VTF=2 XTF=3)
.model PNP2 PNP(IS=1E-14 VAF=100 BF=200 IKF=0.4
+XTB=1.5 BR=4 CJC=1E-12 ITF=1 VTF=2 XTF=3)
*
.ends LM386EE