Creating new element problems

[vlad2015]

 Hello everytbody.

I am trying to create 74AHCG08 AND gate model for multisim. The data file I took from LTspice model library. But it doesn't work for multisim (error: "Unknown component parameter Rpar"). Because of my total incompetence I can't fix the problem myself. Maybe someone can fix the model data or refer me the information required?

thanks in advance. 

.SUBCKT SN74AHCT1G08 a b gnd y vcc
d1 gnd a dio
d2 a vcc dio
d3 gnd b dio
d4 b vcc dio
.model dio d cjo=3p
mpa1 a2 a vcc vcc lvp w=88u l=2u ad=290p pd=10u
mna1 a2 a gnd gnd lvn w=56u l=2u ad=162p pd=10u
mpb1 b2 b vcc vcc lvp w=88u l=2u ad=290p pd=10u
mnb1 b2 b gnd gnd lvn w=56u l=2u ad=162p pd=10u
r1 a2 gnd 100Meg
r2 b2 gnd 100Meg
mpoa 10 a2 vcc vcc lvp w=88u l=2u ad=140p pd=5u
r10 10 3 100Meg
c10 10 vcc 50f Rpar=100Meg
mpob 3 b2 10 vcc lvp w=88u l=2u ad=290p as=140p pd=10u ps=5u
mnoa1 3 a2 gnd gnd lvn w=56u l=2u ad=162p pd=10u
mnob1 3 b2 gnd gnd lvn w=56u l=2u ad=162p pd=10u
mp2 4 3 vcc vcc lvp w=364u l=2u ad=500p pd=10u
mn2 4 3 gnd gnd lvn w=184u l=2u ad=275p pd=10u
mp3 y 4 vcc vcc lvpo w=1080u l=2u ad=1200p pd=30u
mn3 y 4 gnd gnd lvno w=420u l=2u ad=600p pd=30u
cout y gnd 1p Rpar=100Meg
.model lvn nmos level=3 kp=65u vto=0.8 tox=30n nsub=2.8e15 gamma=0.94 phi=0.65 vmax=150k
+ xj=0.11u ld=0.4u theta=0.054
.model lvp pmos level=3 kp=20.3u vto=-0.8 tox=30n nsub=3.3e16 gamma=0.92 phi=0.65 vmax=970k
+ xj=0.63u ld=0.15u theta=0.108
.model lvno nmos level=3 kp=65u vto=0.8 tox=30n nsub=2.8e15 gamma=0.94 phi=0.65 vmax=150k
+ xj=0.11u ld=0.4u theta=0.054
.model lvpo pmos level=3 kp=20.3u vto=-0.8 tox=30n nsub=3.3e16 gamma=0.92 phi=0.65 vmax=970k
+ xj=0.63u ld=0.15u theta=0.108
.ends 

[cdiaz95]

Hey Vlad:

    Usually, the Unknown component error when importing a SPICE model means that this parameter is not supported by Multisim, something like what was mentioned in this forum.

     To eliminate the error you could remove this parameter, but this might cause strange behaviors when simulating. 

[cliff1001]

The problem is that LTSpice allows parasitic resistances to be placed with capacitors and inductors.  Multisim apparently does not.  You just have to remove the reference to Rpar in the line 

cout y gnd 1p Rpar=100Meg

and add a line 

Rpar y gnd 100Meg .

      You are explicitly including this extra part "Rpar" in the net list.