Hi All,
Before I discovered this post, I wrote a VBS script to do primary and secondary channel sorting on a numeric 3 channel block. It may be useful to someone who doesn't want to go down the C code path. I have found it to be fast and (so far) bug-free. It sorts 3 channels (3rd channel values just moved, not sorted) of about 250,000 records each in about 10 s on my old laptop.
Dave.
'Note: this script was written to process 3 channels by sorting the first 2 successively
'(i.e. sorting by first channel then by second) and simply moving the correpsonding values
'of the 3rd channel. The approach could be expanded successively to sort more than 2 channels,
'but other methods may be better (e.g. using external library functions). The channel names are:
'1) Channel1
'2) Channel2
'3) Channel3 (not sorted)
Option Explicit 'Forces the explicit declaration of all the variables in a script.
Dim DefaultGrp
Dim i
Dim TotalSortRows, SortStartPoint, SortEndPoint, SortStartValue
Dim BlockEndDetected
Set DefaultGrp = Data.Root.ActiveChannelGroup
'Note: multiple channel sorting is difficult in DIAdem as there is no standard function to sort
'multiple channels by successively sorting primary, secondary, tertiary etc channels (e.g. like in MS Excel).
'The function ChnMultipleSort() is poorly named as it only sorts one channel and simply moves corresponding
'values in other channels. The approach below is to apply this function twice, first as just described on
'the whole data set and then in a block-wise fashion on everything except the first data channel.
'Sort the entire data set by the first channel.
Call ChnMultipleSort("[]/Channel1","'[]/Channel2','[]/Channel3'",False,True)
'Now sort the second and third channels by the second channel.
i = 1
TotalSortRows = DefaultGrp.Channels("Channel1").Size
Do
'Repeatedly establish a range of rows in the first channel that have equal values. This
'becomes the block for secondary sorting.
SortStartPoint = i
SortStartValue = ChD(i,"[]/Channel1")
BlockEndDetected = False
Do While i < TotalSortRows And Not BlockEndDetected
i = i + 1
If ChD(i,"[]/Channel1") > SortStartValue Then
BlockEndDetected = True
End If
Loop
If BlockEndDetected Then
SortEndPoint = i - 1
Else 'Reached end of data.
SortEndPoint = i
i = i + 1 'Causes Do...While loop termination.
End If
'Sort the block of data identified as having the same value for the first channel.
'Create temporary channels to hold copied blocks of data.
Call DefaultGrp.Channels.Add("TempChn2",DataTypeFloat64,DefaultGrp.Channels.Count + 1)
Call DefaultGrp.Channels.Add("TempChn3",DefaultGrp.Channels("Channel3").DataType,DefaultGrp.Channels.Count + 1)
'Copy blocks of data to be sorted to temporary channels.
Call DataBlCopy("[]/Channel2",SortStartPoint,SortEndPoint - SortStartPoint + 1,"[]/TempChn2",1)
Call DataBlCopy("[]/Channel3",SortStartPoint,SortEndPoint - SortStartPoint + 1,"[]/TempChn3",1)
'Sort the copied block, then overwite back into original data set.
Call ChnMultipleSort("[]/TempChn2","[]/TempChn3",False,True)
Call DataBlCopy("[]/TempChn2",1,DefaultGrp.Channels("TempChn2").Size,"[]/Channel2",SortStartPoint)
Call DataBlCopy("[]/TempChn3",1,DefaultGrp.Channels("TempChn3").Size,"[]/Channel3",SortStartPoint)
'Now delete the temporarily copied data for sorting.
Call DefaultGrp.Channels.Remove("TempChn2")
Call DefaultGrp.Channels.Remove("TempChn3")
Loop While i <= TotalSortRows
