Apex PA50 SPICE Model used in Multisim

[rharker@chem.ufl.edu]

Below I have pasted the SPICE code from Apex for their PA50 power amp.  I tried using the component wizard in Multisim but when I run the simulation I get the following errors:

1st a popup) An error has been found in the Netlist, would you like to proceed anyway?

2nd if I proceed) ------ Checking SPICE netlist for Apex_PA50 - Saturday, July 20, 2013, 12:54:12 PM ------
SPICE Netlist Error in schematic RefDes 'u1', element 'xu1':  Unexpected '6' found on subckt instance line - too many nodes or parameter value missing name.
SPICE Netlist Error in schematic RefDes 'u1', element '<unknown>':  Due to errors, the subckt instance 'xu1' has been omitted from the simulation
======= SPICE Netlist check completed, 2 error(s), 0 warning(s) =======

You SPICE gurus out there know how I can get these kinds of Apex models into multisim?  They really make great amplifiers.

Thanks

Robert Harker

***********

*REVISION 2 18-MAR-2002

*REDUCED INTERACTION OF SLEW RATE WITH CHANGING SUPPLY.

* BEGIN OPAMP MACROMODEL PA50

* PINOUT ORDER  +IN -IN OUT +VB -VB +VS -VS

.SUBCKT PA50 1 2 3 4 5 36 37

J1 10 1 8 JI1

J2 11 2 9 JI2

R3 12 8 1.34E+03

R4 12 9 1.34E+03

I2 12 5 4.50E-04

C1 12 5 5.00E-13

R5 12 5 5.45E+06

R1 4 10 1.59E+03

R2 4 11 1.59E+03

C2 10 11 1.67E-11

I1 4 5 2.64E-02

G1 6 15 11 10 6.28E-04

G2 6 15 12 15 2.81E-08

R6 6 15 1.00E+05

D1 6 15 DD

D2 15 6 DD

C3 6 7 7.50E-12

G3 15 7 15 6 1.00E+01

R7 7 15 1E3

D3 7 16 DD

V1 18 16 5.50E+00

D4 17 7 DD

V2 17 19 5.50E+00

RE1 15 0 0.001

E2 38 0 4 0 1

E3 39 0 5 0 1

R8 7 20 50

C4 20 15 5.80E-11

Q3 37 20 21 QOP

Q4 36 20 22 QON

Q5 36 21 29 QON

Q6 37 22 29 QOP

E4 41 36 38 36 0.69

E5 42 37 39 37 0.69

E6 18 0 41 0 1

E7 19 0 42 0 1

RY1 38 0 10E6

RY2 39 0 10E6

RY3 41 0 10E6

RY4 42 0 10E6

I3 36 21 5.36E-03

I4 22 37 5.36E-03

I5 37 36 1.0E-02

R15 29 3 8.5E-02

DC1 29 36 DO

DC2 37 29 DO

.MODEL DO D(CJO=10PF IS=1.26E-12 RS=2.38E-03)

.MODEL DD D(CJO=0.1PF IS=1E-17)

.MODEL DL D(CJO=3PF IS=1E-13)

.MODEL JI1 NJF (BETA=4.00E-03 IS=3E-16 VTO=-1)

.MODEL JI2 NJF (BETA=4.00E-03 IS=3E-16 VTO=-1.0050)

.MODEL QOP PNP (BF=2.35E+04 IS=1E-14)

.MODEL QON NPN (BF=2.35E+04 IS=1E-14)

.MODEL QLN NPN (BF=100 IS=1E-14)

.MODEL QLP PNP (BF=100 IS=1E-14)

* END OF OPAMP MACROMODEL

.ENDS

************

[johnsold]

Robert,

I do not have Multisim, so I cannot comment directly on adapting the model. And, yes, Apex makes some very interesting amplifiers.

From the error message you posted, I suspect that the problem is in your multism netlist.  No 'xu1' or 'u1' designations exist in the subcircuit listing.  Can you post the listing of the line or lines where you call the PA50 subcircuit?

Lynn

[rharker@chem.ufl.edu]

Here goes the netlist.  OOPS the netlist is more than 10000 characters so I attached a word document if that helps.  Thanks

[johnsold · Accepted solution]

I have not studied your listing but clearly the xU1 call is not in a SPICE compatible format. The PA50 subcircuit definition has 7 nodes. Your xU1 call has 12! The nodes U1_OPEN_11 and U1_OPEN_12 do not exist anywhere else in the document.

Lynn

[rharker@chem.ufl.edu]

http://www.apexanalog.com/wp-content/uploads/2012/10/PA50U_I.pdf

This is the circuit.  An Apex engineer said that there models are compatible with topspice, berkeley spice, pspice, microcap, LTspice and have not heard of Multisim.

[rharker@chem.ufl.edu]

If i count up the nodes by using the external connections suggeseted at Apex there are indeed seven nodes althought there are 12 pins.

[johnsold]

Many SPICE models do not exactly match the pin connections on the package.  Consider that some devices are available in multiple packages with different numbers of pins. When doing circuit board layout, you must match pins exactly of course, but for simulation that  is not always the case.

Lynn