Creating Op Amp Model

[jtex]

Since I am having problems using the Virtual Amp amps, I decide to try to make my own spice model for the Max9910.   I made the model, but it appears I have a pin mapping problem.  I am not sure how to find the mistake or fix it.

The Max9910 Data sheet Lists these Pins:

Iin+ 1

Iin-: 3

Vss: 2

Vout: 4

Vdd: 5

I attached the file

[lacy]

Why create when you can find a ready made one on the internet. This spice model I believe comes from MAXIM. It is below.

Before I post it thought I would like to say that the Virtual Op Amps do need to be looked at by NI to see if there is a definite problem there or whether we are both not understanding something about them. I would say based upon mine and your analysis that there is a problem with them. Also I understand that your are trying to model this IC with all the parameters of the real thing. Sometimes these components don't react the same as their real couterparts. For instance, you can put an extremely high voltage on them and they still will work whereas the real part would burn up. That was all I was trying to tell you about that as it seemed to have a bearing on the compensation capacitor not seeming to work correctly.

Here is the model for the real Max9910

* MAX9910 MACROMODEL
* ----------------------------
* Revision 0. 11/2005
* ----------------------------
* The MAX9910 ultra low supply current opamps operate from a single
* +1.8 to +5.5V supply and feature 200kHz GBW and Rail-to-Rail output. 
* ----------------------------
* Connections
*       1 = IN+
*       2 = VSS
*       3 = IN-
*       4 = OUT
*       5 = VDD   
*-----------------------------
**********************************
.SUBCKT MAX9910 1 2 3 4 5
 XAMP9910 1 2 3 4 5 MAX9910_S
.ENDS
**********************************

**********************************
.SUBCKT MAX9910_S 17 18 15 42 10
**********************************
* 10 = VCC
* 18 = VEE
* 17 = IN+
* 15 = IN-
* 42 = OUT
**************
*INPUT STAGE
VS1 10 11 0V
FSUP 18 10 VS1 1
IBIAS 11 12 1.27U 
M1 13 16 12 12 MOSP
M2 14 15 12 12 MOSP
VOS 17 A16 0.2M
ECMPSRR A16 16 RA 100 1    
RD1 13 18 54.75K    
RD2 14 18 54.75K
C1 13 14 3.93P
**************
*INPUT BIAS CURRENT 
IBIAS1 12 16 1P
IBIAS2 12 15 1P 
**************************************************
*GAIN STAGE 
GA1 100 A1 14 13 10U 
RP1 A1 100 100K
CP1 A1 100 0.5P
********
GA 25 100 A1 100 1M  
RO1 25 100 3.163K
GB 26 100 25 100 1
RO2 26 100 100K
EF 27 100 26 100 1   
RLF 27 100 1MEG 
CC 25 27 695.5P
***************
*VOLTAGE LIMITING
DP1 26 151 DY           
EP1 151 153 10 18 0.5
EP3 153 155 27 199 1
HCOMP1 100 155 VIS2 111.11
DP2 152 26 DY
EP2 154 152 10 18 0.5
EP4 156 154 199 26 1
HCOMP2 100 156 VIS2 111.11
**************************************************
*CMRR (CMRR DC RESPONSE)
RA1 RA 100 1 
GCM RA 100 18 12 100U 
**************************************************
*PSRR (PSRR DC RESPONSE)
GPS 100 RA 10 18 -67.8U
**************************************************
****************
*CURRENT LIMITING
RO3 27 199 162
D1 30 199 DY
D2 199 28 DY
D3 29 28 DY
D4 30 29 DY
ILIM1 28 30 15M
RILIM 28 30 1MEG
**************************************************
VIS2 29 42 0V    
**************************************************
*INTERNAL GND AT VDD/2
EG1 100 18 10 18 0.5
**************************************************
*SUPPLY CURRENT MODEL
*BIAS CURRENT
ISUP 10 18 4U
***************
*LOAD CURRENT
DSUP 18 10 DX        
FIS1 100 60 VIS2 1
D17 100 60 DX
D18 60 61 DX
VIS3 100 61 0V
FSUP1 18 10 VIS3 1
**************
*MAXIMUM INPUT COMMON MODE VOLTAGE LIMIT
DIL 12 80 DZ
RIL 80 82 100 
VIL 82 81 0.8V
EIL 81 18 10 18 1
**************
*MINIMUM SUPPLY VOLTAGE LIMIT 
VVL 85 18 1.8V
VIS4 85 86 0V
RVL 86 87 30K
DVL3 87 88 DY
EVL 88 18 10 18 1
DVL4 18 12 DY
DVL5 12 84 DY
FVL 84 18 VIS4 4 
**************************************************
.MODEL DA D(IS=100E-14 RS=0.5k)
.MODEL MOSP PMOS(VTO=-0.7 KP=261.5U)
.MODEL DX D(IS=100E-14)
.MODEL DZ D(N=10M)
.MODEL DY D(IS=100E-14 N=0.1M)
**************************************************
.ENDS

I hope I have helped in someway and I apoligize for any misunderstandings on my part about your problem.

[jtex]

I did not know there was a model.  How did you find it?  How do I make this model in Spice?

[lacy]

I just done a Google Search for MAX9910 Spice Model and there it was. The only thing you have to do is edit your component in the database. Copy the spice model from the post and paste it into your component that you have created (I think this is what your asking). If your asking how to create spice models in general, then that is a subject that I am not entirely familiar with. I know a little, but not much. Not enouigh to help in any case. This is where you would have to consult a reference manual on Spice or XSpice as I don't have that level of knowledge.

[jtex]

I must have done something wrong because I do not get good AC results.  DC seems to work, but when the output reaches the supply the simulation crashes.

I attached design file.

[lacy]

I am not sure abut this. but you have your gain set to 100. With a 1 volt input multiplied by one hundred would be 100V which is more than the supply voltage. The model has voltage limiting so as not to exceed the supply voltage. I believe this may be what is happening. The only other thing is that the model is not working exactly as it should within Multisim. This model came from Maxim, but that is no sign that it will work correctly in Multisim. I tested it yesterday and didn't have any errors or problems with it in the circuits you posted.

I would lean more toward the voltage limiting of the model causing the problem with you gain set the way it is.

I hope this helps some. This is all could find

[jtex]

Yes, that is what's happening.  But, I think it is an error that the sim crashes.  Should the output stay at the positive supply.  Additional, run an ac sim it the results are incorrect.

[lacy]

"Should the output stay at the positive supply. Additional, run an ac sim it the results are incorrect."

I am not sure what you are referring to in the two statements. Could you please explain further.

As far as the simulator crashing, mine did not crash. It returned a simulation error indicating that something in the circuit wasn't right. You will find that this happens when the circuit has an error. These errors come in many forms including a component model causing an error when some values are exceeded i.e reversing the polarity of the supply voltage.

[jtex]

DC sim:  Output should not exceed the supply voltage; therefore it should latch to 2.515 VDC and not return an error.

AC sim should show a 40dB gain, but the AC analysis does not. 

[lacy]

DC Sim: I never got an error. Don't know why your getting one.

AC Sim: Are you running the AC Analysis in the Simulate>Analysis menu? Or are you using the simulator switch to run the circuit?

Message Edited by lacy on 12-17-2007 07:41 PM