What am i doing wrong when importing a SPICE netlist model?

[08Ultrasound]

Hi,

I'm attempting to import a SPICE netlist model for the first time. I found the netlist off the manufacturers website that produces MOSFETS. I made a new component using the new component wizard using a tutorial i found on here. (Tutorial)

I'm completely new to SPICE netlist models, so i'm learning to read them as i go. I'm i correct in thinking that the line that says .SUBCKT 201N25 10 20 30 is stating the D, G and S respectively? Below is the SPICE netlist i'm attempting to use. It came from this MOSFET datasheet. (Last page)

**********
*SYM=POWMOSN
.SUBCKT 201N25  10 20 30
*     TERMINALS:  D  G  S
*  200 Volt  25 Amp  .08 ohm  N-Channel Power MOSFET  07-29-1993
M1   1 2  3  3  DMOS  L=1U W=1U
RON  5 6 1.5
DON  6 2  D1
ROF  5 7 .2
DOF  2 7  D1
D1CRS 2 8 D2
D2CRS 1 8 D2
CGS  2 3  2.5N
RD   4 1  .08
DCOS 3 1 D3
RDS  1  3  5.0MEG
LS  3 30 .1N
LD  10 4  1N
LG  20 5  1N
.MODEL DMOS NMOS (LEVEL=3 VTO=3.0 KP=25.0)
.MODEL D1 D (IS=.5F CJO=1P BV=100 M=.5 VJ=.6 TT=1N)
.MODEL D2 D (IS=.5F CJO=1100P BV=500 M=.5 VJ=.6 TT=1N RS=10M) 
.MODEL D3 D (IS=.5F CJO=300P BV=500 M=.3 VJ=.4 TT=400N RS=10M)
.ENDS

I've connected the MOSFET to a simple circuit to test that it works correct as a basic switch.(As shown here). 

I've found that the circuit doesn't perform as it should and so i'm wondering what i've done wrong.

Any help is much appreciated.

[_user32]

I configured the model using the Multisim Component Wizard and the model appears to work correctly.  

Most likely you are having problems with the pin mapping step (Step #6 if model only).  In the model the model pin order is 1=D, 2=G and 3=S.   If you've chosen one of the standard symbols the symbol pin order is likely different (in most existing Multisim Mosfets the symbol pin order is S, D, G) and you need to adjust the symbol to model pin order as shown below:

My test circuit is as follows:

Please recheck (Double click and choose the 'Edit component in DB' and select the Model tab to recheck symbol-model pin mapping)...

Regards,

Pat N

[08Ultrasound]

How strange, I thought that is exactly how i had set the SDG leads to the model. I re-allocated SDG leads to the pin numbers and it worked.

Thank you very much for showing me the correct configuration.

I have another model (below) i'm struggling to see which SDG leads attach to which pin numbers. Is there an easy way to check which pins are what? Or is it trial and error?

Below is the SPICE model i'm now attempting to connect up which is a p-channel MOSFET.

.SUBCKT FDMQ8203_Q1Q4_N  2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMQ8203 Spice model                    **
**                    Revision RevA, 26 July 2011               **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 1.503e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.521e-9
RLgate 1 9 15.03
RLdrain 2 5 1
RLsource 3 7 5.21
Rgate 9 6 6.11

* Shielded  Gate  
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 6.58
C_C1 6 101 16e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=0.23e-9 M=0.54 t_abs=25) 

It 7 17 1
Ebreak 11 7 17 7 110.75
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.69e-3 TC2=-0.25e-6)
.MODEL DbodyMOD D (IS=1e-12 n=1.05 RS=23.5e-3 TRS1=1.5e-3 TRS2=1e-6 
+ CJO=0.06e-9 M=0.4 TT=1e-9 XTI=2.75)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 3.445e-3
Rdrain 5 16 RdrainMOD 60.0e-3
.MODEL RdrainMOD RES (TC1=6.45e-3 TC2=19e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=0.37 L=1.15e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=1000e-10
+ XJ=0.62e-6
+ NCH=0.96e17
*Channel Current
+ U0=670 VSAT=500000 DROUT=1.8
+ DELTA=0.05 PSCBE2=0 RSH=3.445e-3
*Threshold voltage
+ VTH0=3.25
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.4
*Junction diodes and Capacitance
+ LINT=0.175e-6 DLC=0.175e-6 
+ CGSO=174e-12 CGSL=0 CGDO=0.5e-12 CGDL=155e-12 
+ CJ=0 CF=0 CKAPPA=0.8
* Temperature parameters 
+ KT1=-2.1 KT2=0 UA1=4.75e-9
+ NJ=10)
.ENDS   
* 
*
.SUBCKT FDMQ8203_Q2Q3_P 2 1 3
*Nom Temp 25 deg C		
Dbody 5 7 DbodyMOD 		
Dbreak 7 11 DbreakMOD 		
Lgate 1 9 0.559e-9		
Ldrain 2 5 0.1e-9		
Lsource 3 7 0.281e-9		
RLgate 1 9 5.59		
RLdrain 2 5 1		
RLsource 3 7 2.81		
Rgate 9 6 1.48		
It 7 17 1		
Ebreak 5 11 17 7 -90		
Rbreak 17 7 RbreakMOD 1 		
.MODEL RbreakMOD RES (TC1=0.95e-3 TC2=-0.2e-6)		
.MODEL DbodyMOD D (IS=0.67e-12 n=1 RS=28e-3 TRS1=0.4e-3 TRS2=4e-6 		
+ CJO=0.01e-9 M=0.65 TT=3e-9 XTI=2.6)		
.MODEL DbreakMOD D (RS=0 TRS1=65e-3 TRS2=300e-6 )		
Rsource 7a 7 4.467e-3		
Rdrain 5 16 RdrainMOD 150e-3		
.MODEL RdrainMOD RES (TC1=6.1e-3 TC2=8.8e-6)		
M_BSIM3 16 6 7a 7a Bsim3 W=0.66 L=1.7e-6 NRS=0 NRD=0		
.MODEL Bsim3 PMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0		
*Process Parameters		
+ TOX=410e-10
+ XJ=1.6ue-6	
+ NCH=1.5e17	
*Channel Current		
+ U0=420 VSAT=100000 DROUT=1.8		
+ DELTA=0.7 PSCBE2=0.00001 RSH=4.467e-3		
*Threshold voltage		
+ VTH0=-1.76		
*Sub-threshold characteristics		
+ VOFF=-0.21 NFACTOR=1.0		
*Junction diodes and Capacitance		
+ LINT=0.4e-6 DLC=0.4e-6 		
+ CGSO=330e-12 CGSL=0 CGDO=20e-12 CGDL=700e-12 		
+ CJ=0 CF=0 CKAPPA=1
* Temperature parameters 		
+ KT1=-1.1 KT2=0 UA1=7.0e-9		
+ NJ=10)		
.ENDS   		

[_user32]

08Ultrasound,

No problem...sounds like an interesting evaluation of MOSFETs that you are working on.

So, it's a little bit more difficult when the external pins of model are not explicitly described in a comment.   For MOSFETs, the tool PSPICE commonly follows a DGS model pin order convention which several of the manufacturers follow (but not all), so you can never be 100% certain until you take a look inside the model...  Here's how you can make certain.

First take a look at the header ... the header for the model is this:

.SUBCKT FDMQ8203_Q1Q4_N  2 1 3

There are 2 things we need to do, first since the model pins do not have any comments to tell you exactly what net 2, net 1 and net 3 are tied to - we need to decipher this for ourselves.  Luckily there are some clues inside the model:

If you look down through the model, there are a few nodes described as follows:

RLgate 1 9 15.03       - this tells me there is a resistor with a name of 'gate' connect to net 1 and 9 - net 1 is an external net from above in the header.
RLdrain 2 5 1             - similarly this 'drain' resistor is connected to external net 2
RLsource 3 7 5.21     - and finally 'source' is connected to external net 3

This tells me the order in the header is as such:

.SUBCKT FDMQ8203_Q1Q4_N  2 1 3     [Order is: DGS]

[where position 1 (net2) = drain, position 2 (net1) = gate and position 3 (net3) = source]

Also in Multisim note that the model node order is important not the names (the names of the nets "2", "1" and "3" have nothing to do with the order when mapping in Multisim.   So from the perspective of Multisim, shown below should be what the symbol - model pin mapping should look like when you do the mapping (For completeness, I added the net names as they appear in the model, but it is the order of the Model nodes from left to right that actually matters in this step):

Hope this helps.  

Also I noticed this is a dual complementary pair type device (2 N channels and 2 P channels).  If you are modeling the entire device, note that this model only models one of the N channel MOSFETs separately.   For a complete component in Multisim that does modeling of all 4 MOSFETs and also maps to a footprint, you would have to go through the steps of creating a multisection component and you'd need to map each of the 4 sections (2 N ch, 2 P ch) to the right model individually (and also take care of footprint pin mapping if needed).

If you did go through these steps, it would be fantastic to post the final part you've created in an empy schematic so that others could share this component if needed.   We actually have the NI Circuit Design Community page dedicated for just this type of sharing activity.

- Pat N